Скетч для Arduino OLED дисплея

Скачать библиотеку OLED дисплея, на контроллере SH1106

Пример скетча для Arduino из библиотеки:

#include <wire.h>
#include <oled_sh1106.h>

#define OLED_RESET 4
OLED_SH1106 display(OLED_RESET);

#define NUMFLAKES 10
#define XPOS 0
#define YPOS 1
#define DELTAY 2

#define LOGO16_GLCD_HEIGHT 16 
#define LOGO16_GLCD_WIDTH  16 
static const unsigned char PROGMEM logo16_glcd_bmp[] =
{ B00000000,B11000000,
  B00000001,B11000000,
  B00000001,B11000000,
  B00000011,B11100000,
  B11110011,B11100000,
  B11111110,B11111000,
  B01111110,B11111111,
  B00110011,B10011111,
  B00011111,B11111100,
  B00001101,B01110000,
  B00011011,B10100000,
  B00111111,B11100000,
  B00111111,B11110000,
  B01111100,B11110000,
  B01110000,B01110000,
  B00000000,B00110000 };

#if (SH1106_LCDHEIGHT != 64)
#error("Height incorrect, please fix OLED_SH1106.h!");
#endif

void setup()   
{                
  display.begin(SH1106_SWITCHCAPVCC, 0x3C);  // Инициализация I2C с адресом 0x3C (для 128x64)
  display.display();
  delay(5000); 

  // очистить буфер
  display.clearDisplay();

  // рисуем точку в центре дисплея
  display.drawPixel(64, 32, WHITE);
  display.display();
  delay(1000);
  display.clearDisplay();

  // Рисуем линии
  testdrawline();
  display.display();
  delay(1000);
  display.clearDisplay();

  // рисуем прямоугольник
  testdrawrect();
  display.display();
  delay(1000);
  display.clearDisplay();

  // рисуем прямоугольники
  testfillrect();
  display.display();
  delay(1000);
  display.clearDisplay();

  // рисуем окружности
  testdrawcircle();
  display.display();
  delay(1000);
  display.clearDisplay();

  // рисуем белую окружность, радиус 10 пикселей 
  display.fillCircle(display.width()/2, display.height()/2, 10, WHITE);
  display.display();
  delay(1000);
  display.clearDisplay();

  // прямоугольник со скругленными углами
  testdrawroundrect();
  delay(1000);
  display.clearDisplay();
  //прямоугольники со скругленными углами
  testfillroundrect();
  delay(1000);
  display.clearDisplay();

  //треугольник
  testdrawtriangle();
  delay(1000);
  display.clearDisplay();
   //треугольники
  testfilltriangle();
  delay(1000);
  display.clearDisplay();

  // распечатываем шрифт
  testdrawchar();
  display.display();
  delay(1000);
  display.clearDisplay();

// Пишем текст ШИРИНА СИМВОЛА 6 ТОЧЕК, ВЫСОТА 8 ТОЧЕК
  display.setTextColor(WHITE); //цвет текста
  display.setCursor(2*6,2*8); //начальное положение на экране в пикселях
  display.setTextSize(2); //удвоенный размер текста
  display.println("DUINO.RU");

  display.setTextSize(1); //стандартный размер теста
  display.setTextColor(BLACK, WHITE); // инвертировать текст
  display.println("   Arduino  store   ");
  display.display();    //прорисовка на экране
  delay(5000);

  // вывести на дисплее изображение 16х16
  display.clearDisplay();
  display.drawBitmap(30, 16, logo16_glcd_bmp, 16, 16, 1);
  display.display();

  // инвертировать дисплей
  display.invertDisplay(true);
  delay(1000); 
  display.invertDisplay(false);
  delay(1000); 

  // анимация с изображением logo16_glcd_bmp
  testdrawbitmap(logo16_glcd_bmp, LOGO16_GLCD_HEIGHT, LOGO16_GLCD_WIDTH);
}

void loop() 
{  
}
 void testdrawbitmap(const uint8_t *bitmap, uint8_t w, uint8_t h) 
{
  uint8_t icons[NUMFLAKES][3];
 
  // initialize
  for (uint8_t f=0; f< NUMFLAKES; f++) {
    icons[f][XPOS] = random(display.width());
    icons[f][YPOS] = 0;
    icons[f][DELTAY] = random(5) + 1;
  }

  while (1) 
  {
    // draw each icon
    for (uint8_t f=0; f< NUMFLAKES; f++)
    {
      display.drawBitmap(icons[f][XPOS], icons[f][YPOS], logo16_glcd_bmp, w, h, WHITE);
    }
    display.display();
    delay(200);
    
    // then erase it + move it
    for (uint8_t f=0; f< NUMFLAKES; f++) 
    {
      display.drawBitmap(icons[f][XPOS], icons[f][YPOS],  logo16_glcd_bmp, w, h, BLACK);
      // move it
      icons[f][YPOS] += icons[f][DELTAY];
      // if its gone, reinit
      if (icons[f][YPOS] > display.height()) 
      {
          icons[f][XPOS] = random(display.width());
          icons[f][YPOS] = 0;
          icons[f][DELTAY] = random(5) + 1;
      }
    }
   }
}

void testdrawchar(void) 
{
  display.setTextSize(1);
  display.setTextColor(WHITE);
  display.setCursor(0,0);

  for (uint8_t i=0; i < 168; i++) 
  {
    if (i == '\n') continue;
    display.write(i);
    if ((i > 0) && (i % 21 == 0))
      display.println();
  }    
  display.display();
}

void testdrawcircle(void)
{
  for (int16_t i=0; i<display.height(); i+=2)
  {
    display.drawCircle(display.width()/2, display.height()/2, i, WHITE);
    display.display();
  }
}
void testfillrect(void) 
{
  uint8_t color = 1;
  for (int16_t i=0; i<display.height()/2; i+=3)
  {
    // alternate colors
    display.fillRect(i, i, display.width()-i*2, display.height()-i*2, color%2);
    display.display();
    color++;
  }
}

void testdrawtriangle(void) 
{
  for (int16_t i=0; i<min(display.width(),display.height())/2; i+=5)
  {
    display.drawTriangle(display.width()/2, display.height()/2-i,
                     display.width()/2-i, display.height()/2+i,
                     display.width()/2+i, display.height()/2+i, WHITE);
    display.display();
  }
}

void testfilltriangle(void) 
{
  uint8_t color = WHITE;
  for (int16_t i=min(display.width(),display.height())/2; i>0; i-=5)
  {
    display.fillTriangle(display.width()/2, display.height()/2-i,
                     display.width()/2-i, display.height()/2+i,
                     display.width()/2+i, display.height()/2+i, WHITE);
    if (color == WHITE) color = BLACK;
    else color = WHITE;
    display.display();
  }
}

void testdrawroundrect(void) 
{
  for (int16_t i=0; i<display.height()/2-2; i+=2)
  {
    display.drawRoundRect(i, i, display.width()-2*i, display.height()-2*i, display.height()/4, WHITE);
    display.display();
  }
}

void testfillroundrect(void) 
{
  uint8_t color = WHITE;
  for (int16_t i=0; i<display.height()/2-2; i+=2)
  {
    display.fillRoundRect(i, i, display.width()-2*i, display.height()-2*i, display.height()/4, color);
    if (color == WHITE) color = BLACK;
    else color = WHITE;
    display.display();
  }
}
   
void testdrawrect(void) 
{
  for (int16_t i=0; i<display.height()/2; i+=2)
  {
    display.drawRect(i, i, display.width()-2*i, display.height()-2*i, WHITE);
    display.display();
  }
}

void testdrawline() {  
  for (int16_t i=0; i<display.width(); i+=4)
  {
    display.drawLine(0, 0, i, display.height()-1, WHITE);
    display.display();
  }
  for (int16_t i=0; i<display.height(); i+=4)
  {
    display.drawLine(0, 0, display.width()-1, i, WHITE);
    display.display();
  }
  delay(250);
  
  display.clearDisplay();
  for (int16_t i=0; i<display.width(); i+=4)
  {
    display.drawLine(0, display.height()-1, i, 0, WHITE);
    display.display();
  }
  for (int16_t i=display.height()-1; i>=0; i-=4)
  {
    display.drawLine(0, display.height()-1, display.width()-1, i, WHITE);
    display.display();
  }
  delay(250);
  
  display.clearDisplay();
  for (int16_t i=display.width()-1; i>=0; i-=4)
  {
    display.drawLine(display.width()-1, display.height()-1, i, 0, WHITE);
    display.display();
  }
  for (int16_t i=display.height()-1; i>=0; i-=4)
  {
    display.drawLine(display.width()-1, display.height()-1, 0, i, WHITE);
    display.display();
  }
  delay(250);

  display.clearDisplay();
  for (int16_t i=0; i<display.height(); i+=4)
  {
    display.drawLine(display.width()-1, 0, 0, i, WHITE);
    display.display();
  }
  for (int16_t i=0; i<display.width(); i+=4)
  {
    display.drawLine(display.width()-1, 0, i, display.height()-1, WHITE); 
    display.display();
  }
  delay(250);
}